ＰＩＣ−ＵＳＢＩＯ ｕｓｉｎｇ ＢＡＳＩＣ
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
ＵＳＢインターフェースを内蔵したＰＩＣを使ってＷｉｎｄｏｗｓパソコンで外部回路を制御するための各種Ｉ／Ｏ基板の製作記事です。
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
［第１９０回］
●ＰＩＣＵＳＢＩＯ用ＢＡＳＩＣ説明書（５）ＢＡＳＩＣ命令
今回はＢＡＳＩＣ説明書の第５回です。
５章 ＢＡＳＩＣ命令（ステートメント）
命令（ステートメント）はＢＡＳＩＣプログラム中でそれぞれの動作を指定するのに使われます。
この命令と次章で説明する関数がＢＡＳＩＣの主要な構成要素です。
したがってこの命令と関数の働きを理解すればＢＡＳＩＣプログラムは自由に使いこなすことができます。
命令はコマンドモードでダイレクトに実行することもできます。
ＣＬＯＳＥ ＃ｎ
ファイルをクローズするための命令です。
オープンしたファイルは最後にクローズして終る必要があります。
ＣＬＯＳＥ命令を実行しないでプログラムを終了するとオープンしているファイルは破棄されてしまいます。
ＢＡＳＩＣを／ＥＸＩＴかまたは［Ｃｔｒｌ］＋［Ｃ］で終了するとそのときオープンしているファイルに対しては強制的にＣＬＯＳＥ命令が実行されます。
使用例や使い方については［第７回］、［第８回］を参照してください。
ＤＡＴＡ
ＲＥＡＤ文で読み込まれる数値を定義します。
ＲＥＡＤ文より前にあっても後ろにあっても構いません。
複数のＤＡＴＡ文を書いても構いません。
ＲＥＡＤ文は小さい行番号のＤＡＴＡ文から順に読んで行きます。
整数および文字定数をカンマ（ ，）で区切って複数個記述できますがその型がＲＥＡＤ文の変数の型と一致しない場合は実行時にエラーになります（数値を文字型変数に読み込むことはできますが文字を整数型変数に読み込むことはできません）。
文字定数は” ”でくくらないでそのまま表記します（” ”を使うと” ”は無視されます）。
［使用例］
１０ ＤＡＴＡ １２３，ＡＢＣＤＥ，４５６７
：
５０ ＲＥＡＤ Ａ，Ｙ＄
：
９０ ＲＥＡＤ Ｚ
１００ ＰＲＩＮＴ Ａ，Ｙ＄，Ｚ
＞ＲＵＮ
１２３ ＡＢＣＤＥ ４５６７
［注意］ＤＡＴＡ文はマルチステートメント記述（複数の命令を：で区切って同じ行に続けて書くこと）はできません。
ただしその行にラベルをつけて下のように記述することは許されます。
［許される使用例］
１００ ＊ＡＢＣ：ＤＡＴＡ １２３，ＡＢＣＤＥ，４５６７
ＤＩＭ
配列変数を定義します。
３次までの整数型の配列を使うことができます。
普通の変数はＬＥＴ文で値を入れるときに変数名の定義も同時に行ってしまうのですが配列はまずＤＩＭ文で配列名とその配列の大きさを定義してからでないと使うことができません。
ＤＩＭ文では名前と大きさ（１次〜３次の別、要素の数）を定義するだけで個々の配列要素には初期値は入りません。
各配列要素にはＤＩＭ文で定義したあとでＬＥＴ文で値をセットします。
ＤＩＭ文はプログラム中のどこにあっても構いませんがプログラムの途中に置くのはプログラムミスのもとにもなりますからできるだけプログラムの始めの部分に書いておく方がよいでしょう。
一つのＤＩＭ文の中で複数の配列名を定義することもできますし一つのプログラムの中で何回ＤＩＭ文を使用しても構いません。
［使用例］
10 DIM AKA(3,5,2),KI(6,3)
上の文によって整数型配列ＡＫＡ（ａ，ｂ，ｃ）（ａ＝０〜３、ｂ＝０〜５、ｃ＝０〜２）整数型配列ＫＩ（ｄ，ｅ）（ｄ＝０〜６、ｅ＝０〜３）が定義されます。
ＤＩＭ文で定義しない配列名を他の文の中で使用したりあるいは添字（カッコ内の要素を示す数値）の値としてＤＩＭ文で定義した数よりも大きい数を用いたりするとエラーコードが出されます。
［注意１］普通の変数名と配列名とで同じ名前を使用してはいけません。
［注意２］ＤＩＭ命令はダイレクトモードでは使用できません。
ＦＯＲ〜ＮＥＸＴ
［書式］
ＦＯＲ 変数名（または配列名）＝開始値 ＴＯ 終了値 ＳＴＥＰ 増分
：
ＮＥＸＴ 変数名（または配列名）
ＦＯＲ文からこれに対応するＮＥＸＴ文までの間の命令を指定条件が満たされるまで繰り返し実行します。
変数名（または配列名）には開始値がセットされて、ＦＯＲ文とＮＥＸＴ文の間にある文が実行され、次にその変数名（または配列名）の値に増分が加算されて、またＦＯＲ文とＮＥＸＴ文の間にある文が実行されます。
繰り返し実行された結果変数名（または配列名）の値が終了値を越えるとこのループから抜け出てＮＥＸＴ文の次の文が実行されます。
［使用例］
１０ ＦＯＲ Ａ＝３ ＴＯ １６ ＳＴＥＰ ２
２０ ＰＲＩＮＴ Ａ，；
３０ ＮＥＸＴ Ａ
４０ ＰＲＩＮＴ ”ＥＮＤ”，Ａ
＞RUN［Ｅｎｔｅｒ］
3 5 7 9 11 13 15 END 17
この例ではＡ＝３からはじまって２ずつ増加しながら１０〜３０の文を繰り返し実行し１６を越えたら、つまり１７になったところでＮＥＸＴの次の文に移ります。
Ａ＝１７のときにはループの中の処理は行われないで外に出ます（Ａ＝１５までしか実行されていないことに注意して下さい）。
［注記１］開始値、終了値、増分ともにマイナス値を入れることもできます。
増分にマイナス値を指定するとカウンタの値は順に減って行きます。
増分にマイナス値を指定した場合には変数の値が終了値よりも小さくなった時点でループから抜け出します。
［注記２］ＳＴＥＰを省略することもできますがこのときは増分は１になります。
［注記３］ＦＯＲ〜ＮＥＸＴ文の中に別のＦＯＲ〜ＮＥＸＴ文を多重に使用することができます。
多重使用（ネスティング）はシステムのスタックエリアをそれだけ多く使用するため限度を越えるとエラーコードが表示されます。
ＧＯＳＵＢ文でも使用されるためＦＯＲ〜ＮＥＸＴ文を何重に使用できるかはそのプログラムによって異なります。
ＦＯＲ〜ＮＥＸＴ文を多重使用する場合には内側のループ文は外側のループ文に完全に含まれていなければなりません。
（正） （誤）
１０ ＦＯＲ Ａ＝１ ＴＯ ２０ １０ ＦＯＲ Ａ＝１ ＴＯ ２０
： ：
５０ ＦＯＲ Ｂ＝３ ＴＯ ６０ ５０ ＦＯＲ Ｂ＝３ ＴＯ ６０
： ：
１２０ ＮＥＸＴ Ｂ １２０ ＮＥＸＴ Ａ
： ：
２００ ＮＥＸＴ Ａ ２００ ＮＥＸＴ Ｂ
： ：
誤って使用した場合にはエラーコードが表示されます。
次の例は外にまたがっているようですがまた戻って来ているので、誤りではありません。
１０ ＦＯＲ Ａ＝１ ＴＯ ２０
：
５０ ＦＯＲ Ｂ＝３ ＴＯ ６０
：
７０ ＧＯＴＯ ２６０
：
１００ Ｘ＝Ｘ＋１
：
２００ ＮＥＸＴ Ａ
：
２２０ ＳＴＯＰ
：
２６０ ＰＲＩＮＴ Ａ
：
２８０ ＮＥＸＴ Ｂ
：
３００ ＧＯＴＯ １００
ＧＯＳＵＢ〜ＲＥＴＵＲＮ
サブルーチンの呼び出し、及びサブルーチンからの戻りを制御します。
ＧＯＳＵＢ文で指定する行から始まるサブルーチンを実行しＲＥＴＵＲＮ文でさきほどのＧＯＳＵＢ文の次の文に戻ります。
行番号の指定は正の整数のほか＊マーク付のラベル名も許されます。
指定した行番号、ラベル名が存在しないときはエラーコードが表示されます。
ＧＯＴＯ文と似ていますが、ＧＯＳＵＢ文の場合にはＲＥＴＵＲＮ文をみつけると先程のＧＯＳＵＢ文の場所に戻ってその次の文から実行を続けます。
サブルーチンはこのように呼ばれた先へまた戻って行くので同じ処理を違う場所で何回も行いたいときに使うと便利です。
［使用例１］
１０ ＧＯＳＵＢ ３００ ………行番号３００から始まるサブルーチンに行く
５０ ＧＯＳＵＢ ＊ＡＢＣ ………ラベル名＊ＡＢＣの書かれたサブルーチンに行く
［使用例２］
１０ ＧＯＳＵＢ １００
２０ Ａ＝Ａ＋１
：
５０ ＧＯＳＵＢ １００
６０ Ｂ＝Ａ
：
９０ ＳＴＯＰ ……忘れないように！
１００ ＰＲＩＮＴ Ａ，Ｂ
：
１５０ ＲＥＴＵＲＮ
１つのプログラムの中でサブルーチンはいくつ使っても構いません。
またサブルーチンの中で別のサブルーチンを呼び出すサブルーチンの多重使用も許されますがＦＯＲ〜ＮＥＸＴと同様にＧＯＳＵＢとＲＥＴＵＲＮがペアになっている必要があります。
サブルーチンの中でＧＯＴＯ（特に ＩＦ ＧＯＴＯが間違いやすい）を多用するとＲＥＴＵＲＮ文を実行しないでまたもとのＧＯＳＵＢ文を実行してしまうようなプログラムになってしまうことがあります。
このような場合には急速にスタックを消費するためやがてエラーになってしまいます。
またＧＯＳＵＢ文を実行していないのにＧＯＴＯ文でサブルーチンの途中に入ってしまいＲＥＴＵＲＮ文を実行してしまうようなプログラムになることがあります。
この場合もエラーコードが表示されます。
ＧＯＴＯ
指定する行にジャンプしてそこから実行を続けます。
行番号の指定は正の整数のほか＊マーク付のラベル名も許されます。
指定した行番号、ラベル名が存在しないときはエラーコードが表示されます。
［使用例］
１０ ＧＯＴＯ ３００ …………行番号３００にジャンプする
５０ ＧＯＴＯ ＊ＡＢＣ …………ラベル名＊ＡＢＣの行にジャンプする
ＩＦ… ＴＨＥＮ
ＩＦの後に続く式（関係式または論理式）の結果が真であればＴＨＥＮより後ろの文を実行し偽であればその次の行が実行されます。
ＩＦ ＴＨＥＮ ＥＬＳＥの形はありません。
［例］
１０ ＩＦ Ａ＜１０ ＰＲＩＮＴ ”ＹＥＳ”：ＧＯＴＯ １００
２０ ＰＲＩＮＴ ”ＥＮＤ”
Ａが１０以下の場合はＰＲＩＮＴ ”ＹＥＳ”とＧＯＴＯ １００の文が実行され１０以上の時は２０行が実行されます。
ＩＦ ．．． ＴＨＥＮ ＧＯＴＯ の場合はＩＦ ．．． ＧＯＴＯのように書くこともできます。
［２３．３．６ 注記］この項を訂正しました。
経緯については［第１９２回］を参照してください。
●文字型の比較
関係演算子（＝、＜、＞、＜＝、＞＝、＃）を使って、文字の大小比較ができます。
文字型の比較は文字数の多い方が大になります。
同じ文字数の場合には先頭から１文字ずつキャラクタコードを比較していき最初に大きいキャラクタコードの文字があらわれた方が大になります。
ＩＮＰＵＴ
キーボードから変数または配列にデータを入力します。
入力データとして定数以外の変数名、配列名や式を入力することはできません。
ＰＲＩＮＴ文などと同じく要素を ，で区切って複数個記述することができます。
［使用例］
１０ ＩＮＰＵＴ Ａ，Ｂ，Ｃ
プログラムが実行されるとまず、Ａ？と表示して入力待ちになります。
そしてこれに答えると次に、Ｂ？と表示して再び入力待ちになります。
このようにしてすべてのデータが入力されるまで繰り返し入力が行われます。
●ＩＮＰＵＴ文にはＰＲＩＮＴ文と同じ文字列表示機能があります。
次のように文字列を” ”で囲んで記述することによりその文字列を表示させることができます。
［使用例］
１０ ＩＮＰＵＴ”ＤＡＴＡ”，Ａ，”ＮＩＮＺＵ ”，Ｃ
＞ＲＵＮ［Ｅｎｔｅｒ］
ＤＡＴＡＡ？ ………これに入力すると、その次が表示される
ＮＩＮＺＵ Ｃ？
文字列と変数との間のカンマ（ ，）を省略すると変数名及び？の表示が省略されます。
１０ ＩＮＰＵＴ”ＤＡＴＡ”Ａ，”ＮＩＮＺＵ ”Ｃ
＞ＲＵＮ［Ｅｎｔｅｒ］
ＤＡＴＡ ………これに入力すると、その次が表示される
ＮＩＮＺＵ
［注記］ＩＮＰＵＴ文が実行されると、コマンドモードと同じようにカーソルマークが表示されますが、この時はコマンドモードとは別の入力方式になっているため［Ｉｎｓｅｒｔ］［Ｄｅｌｅｔｅ］［←］［→］［↑］［↓］は使用できません。［Ｂａｃｋｓｐａｓｅ］は使用できます。
ＬＥＴ
変数、配列に値を代入します
ＬＥＴ Ａ＝３
ＬＥＴ Ｂ＝（Ｃ＋Ｄ）／Ａ
上記のように左辺は、変数、配列でなければなりませんが右辺は定数、式も許されます。
式の場合はその式を計算した結果が変数に格納されます。
ＬＥＴは完全に省略することができ、例えば
ＬＥＴ Ａ＝Ａ＋３ は
Ａ＝Ａ＋３
と表記することができます。
これは数学的にはおかしいのですがこの＝は等号ではなく代入記号として用いられていると考えて下さい。
つまり Ａ＝（イコール）Ａ＋３ではなくて、ＡにＡ＋３の結果を代入する、の意味です。
［使用例］
１０ ＬＥＴ Ａ＝１：ＬＥＴ Ｂ＝０：ＬＥＴ Ｃ（Ｄ，５）＝３＋Ａ：ＬＥＴ Ｘ＄＝”ＡＢＣ”
ＬＥＴは省略することができます
１０ Ａ＝１：Ｂ＝０：Ｃ（Ｄ，５）＝３＋Ａ：Ｘ＄＝”ＡＢＣ”
文字型の場合には＝の右側には文字定数、文字変数を書くことができますが式としては次の例のように複数の文字変数、文字定数、文字関数を ＋ でつないで書くことのみが許されます。
［使用例］
１０ Ａ＄＝”ＡＢＣ”：Ｂ＄＝”ＸＹＺ”
２０ Ｃ＄＝Ａ＄＋”ＨＩＪＫ”＋Ｂ＄＋ＣＨＲ＄（＄４２）
３０ ＰＲＩＮＴ Ｃ＄
＞ＲＵＮ［Ｅｎｔｅｒ］
ＡＢＣＨＩＪＫＸＹＺＢ
＞
［注意］文字変数には最大３９桁の文字列しか代入できません。
もしそれよりも大きい文字列を代入しようとするとエラーコードが表示されます。
ＯＮ ＥＲＲＯＲ ＧＯＴＯ
プログラムの実行中にエラーが発生した場合にこの文で指定する行番号の文が実行されます。
このときシステム変数ＥＲＬにはエラーが発生した行番号がセットされＥＲＣにはエラーの種類を示すコードがセットされます。
この文はエラーが発生するより前に実行されている必要があります。
したがってプログラムの一番先頭に書いておくようにします。
存在しない行番号を指定した場合エラーが発生してもエラー処理ルーチンは実行されずにエラーコードを表示してブレイクします。
エラー処理ルーチンの終わりはＲＥＳＵＭＥ文かＳＴＯＰ文である必要があります（［注意］（３）参照）。
［使用例］
１０ ＯＮ ＥＲＲＯＲ ＧＯＴＯ １００
２０ ＩＮＰＵＴ Ａ，Ｂ
３０ ＰＲＩＮＴ Ａ／Ｂ
４０ ＧＯＴＯ ２０
１００ ＰＲＩＮＴ ”ＥＲＲＯＲ！”，ＥＲＬ，ＥＲＣ
１１０ ＲＥＳＵＭＥ ＮＥＸＴ
上のプログラムを実行して、Ｂに０を入力すると下のように表示されます。
ＥＲＲＯＲ！ ３０ １２ …エラーコード１２は０除算エラーです
Ａ？
［注意］エラー処理ルーチンには通常の命令文を自由に使用して構いません。
行数の制限はありません。
エラー処理ルーチンと普通のルーチンとはみかけ上は区別できませんが次の点が異なっています。
（１）エラー処理ルーチンの実行中に[Ｃｔｒｌ]Ｂによりブレイクした場合、ＣＯＮＴコマンドで実行を再開することはできません。
（２）エラー処理ルーチンの実行中にエラーが発生した場合には、ＯＮ ＥＲＲＯＲ ＧＯＴＯ文は実行されずエラーコードを表示してブレイクします。
この場合もブレイク後にＣＯＮＴコマンドで実行を再開することはできません。
（３）ＲＥＳＵＭＥ文によりエラー処理ルーチンが終了しメインルーチンの実行継続に必要な情報がセットしなおされます。
たとえばＦＯＲ〜ＮＥＸＴやＧＯＳＵＢ〜ＲＥＴＵＲＮ文の途中でエラーが発生して、ＯＮ ＥＲＲＯＲ ＧＯＴＯ文によりエラー処理が行われたあと、ＲＥＳＵＭＥ文によらずにＧＯＴＯ文などでもとのルーチンに戻るとスタックの食い違いにより異常な動きになります。
ＢＡＳＩＣ命令の説明の途中ですが、長くなりましたので今回はここまでとします。
この続きは次回にいたします。
ＰＩＣ−ＵＳＢＩＯ ｕｓｉｎｇ ＢＡＳＩＣ［第１９０回］
２０２３．３．２ｕｐｌｏａｄ
前へ
次へ
ホームページトップへ戻る