２０１３．３．２５
前へ
次へ
ホームページトップへ戻る

復活！ＣＰ／Ｍ　ワンボードマイコンでＣＰ／Ｍを！
ＣＰ／ＭがＴＫ－８０互換のワンボードマイコンの上で復活します
ＮＤ８０ＺⅢとＭＹＣＰＵ８０の上でＣＰ／Ｍが走ります！

［第３５６回］


●メタイベント（ＦＦ）の処理

前回からの続きです。
前回はＭＩＤＩイベントデータの第１コードを解読して、それぞれの処理に分岐するところまでを説明しました。
今回はそれぞれに分岐したあとの処理について説明をします。

ＭＩＤＩイベントデータの第１バイトがＦＦはメタイベントです。
それに続く第２バイトのコードによって、テンポであるとか、曲名とか楽器名とかというようにＭＩＤＩ音源には送らないでＭＩＤＩシーケンスプログラム内で処理される情報を示します。

8107 23       CODEFF:INC HL
8108 7E         LD A,(HL)
8109 FE2F       CP 2F
810B CA3381     JP Z,TRKEND
810E FE51       CP 51
8110 CA7081     JP Z,TMPSET
              ;pass text data or something
8113 23         INC HL
8114 CD1682     CALL VLREAD
8117 19         ADD HL,DE;pass to next data top(variable length top)

メタイベントコードの第２バイトは００～７Ｆまでが許されるのですが、全てのコードは使われていないようです。
そのうちＭＩＤＩ演奏プログラムでとりあえず必要なものはコード２Ｆ（トラックエンド）と５１（テンポ）だけです。
詳しく見ていけばそのほかにも必要なものがあるかも知れませんが、とりあえず上記の２つのコードを処理するだけで、今までのところ特にＭＩＤＩファイルの演奏には支障はないようです。

第２バイトが２Ｆはトラックの終わりを示します。
ＴＲＫＥＮＤにジャンプします。
第２バイトが５１はテンポを示します。
ＴＭＰＳＥＴにジャンプします。
コード２Ｆ、５Ｆのときの各ジャンプ先での処理についてはのちほど説明をします。

第２バイトが０１～０９は曲名や楽器名などのテキスト文字を表記するのに使われます。
このコードに限らずメタイベントの第３バイトには可変長表記でそれに続くデータのバイト数が置かれます。
そこで上記の２Ｆ、５１以外はそのバイト数を読んで、データ部分をスルーします。
ＶＬＲＥＡＤは可変長データを１６進数表記に変換してＤＥレジスタに格納するサブルーチンです（［第３５１回］参照）。
ＨＬレジスタには可変長データの次のアドレスが入っていますから、それにＤＥレジスタの値を加算することで、データ部分をスルーします。

スルーしたあとは、その次に書かれているＭＩＤＩイベントデータの読み込み処理に入ります。

●次のＭＩＤＩイベントデータのセット（ＮＥＸＴＤＴ）

次のＭＩＤＩイベントデータの読み込み処理ルーチンＮＥＸＴＤＴです。

8118 CD1682   NEXTDT:CALL VLREAD
811B DD7302     LD (IX+02),E
811E DD7203     LD (IX+03),D
8121 DD7004     LD (IX+04),B
8124 78         LD A,B
8125 B2         OR D
8126 B3         OR E
8127 DD7701     LD (IX+01),A
812A DD7505     LD (IX+05),L
812D DD7406     LD (IX+06),H
8130 C33781     JP NEXT

イベントデータの前には必ず可変長形式の時間データが置かれています。
ＣＡＬＬ　ＶＬＲＥＡＤを実行すると可変長データをが１６進数データ３バイトに変換され、Ｂ、Ｄ、Ｅの各レジスタに格納されます。
その３バイトの時間データを（ＩＸ＋０２）～（ＩＸ＋０４）に書き込みます。
そしてその３バイトのＯＲを（ＩＸ＋０１）に入れます。
（ＩＸ＋０１）が００になるのは、時間データが０のときだけです。

ここではそのように書き込むデータの順序が重要です。
割り込みプログラムが常に動いていることを忘れてはいけません。
自分で言うのもおかしいのですが、このＭＩＤＩ演奏プログラムは周到に計算して作成されているのです。

割り込みプログラムは非常に危険なプログラムです。
扱いを誤るとたちどころに暴走してしまいます。
このプログラムで危険なのは、時間データが複数バイトから成っていることです。

割り込みプログラムはメインプログラムが処理をしているどんなタイミングでも実行されてしまう可能性があります（もちろん、もし割り込みが許可されていれば、ですが）。
ここではメインプログラムが３バイトの時間データを（ＩＸ＋０２）～（ＩＸ＋０４）に順に格納しています。
もしも、（ＩＸ＋０２）または（ＩＸ＋０３）にデータを書き込んで、まだ（ＩＸ＋０４）にはデータが書き込まれていないときに割り込みが発生したとしたら何がおきるでしょうか。

割り込みプログラムは（ＩＸ＋０２）～（ＩＸ＋０４）が正しい時間データであるという前提で、その値を－１します。
当然その結果は誤ったものになります。
さらに割り込みプログラムがそのようにして計算した結果を（ＩＸ＋０２）～（ＩＸ＋０４）に書き込んでリターンしたあとで、保留されていたメインプログラムの実行が再開され、そこで残されていた（ＩＸ＋０４）に値が書き込まれます。
めちゃくちゃになってしまうことがお分かりいただけると思います。

このプログラムが周到に計算されている、と書きましたのはそこなのです。
（ＩＸ＋０１）は時間データが０のときのみ００になります。
これによって３バイトの時間データを参照しなくても（ＩＸ＋０１）だけを見れば、時間データが０であることが判断できますから、処理が簡単になります。
しかし実は（ＩＸ＋０１）にはもっと重要な役割があるのです。
（ＩＸ＋０１）が００の時には、割込み処理がスルーされるようになっています。
時間データが０ならそれでカウントダウンは終わりですから、割り込みが発生しても、このトラックに対しては割り込み処理は行なわれません。

ところでここは次に処理をするイベントデータの前に置かれている時間データをメモリに書き込むところなのですが、書き込む直前の（ＩＸ＋０１）の値はどうなっているでしょうか？
実はこのとき（ＩＸ＋０１）の値は必ず００なのです。
今までの説明をもういちど読んでみてください。
すると、（ＩＸ＋０１）の値が００だから、ＭＩＤＩイベントデータの処理をして、それが終ったから、ここに来たということが分かりますでしょう。

ここでは（ＩＸ＋０１）が割り込み禁止の役目を果たしているのです。
ですからたとえ（ＩＸ＋０２）～（ＩＸ＋０４）の途中を書き込んでいるときに割込みが発生したとしても、割込みプログラムがその書き込み途中の値をカウントダウンしてしまうことは決してありません。

そして３バイトの値を書き込んだあとで（ＩＸ＋０１）の値を更新します。
そういう順序でなければならない、ということがお分かりいただけたと思います。

最後にイベントデータの先頭アドレスが入っているＨＬレジスタの値を（ＩＸ＋０５）と（ＩＸ＋０６）に書き込んで、次のトラックの処理（ＮＥＸＴ）に行きます。

●トラックの終わり（ＴＲＫＥＮＤ）と次のトラックヘの処理（ＮＥＸＴ）

メタイベント　ＦＦ　２Ｆ　００　は、トラックの終わりを示します。
ＴＲＫＥＮＤはトラックの終わりの処理です。

8133 DD360000 TRKEND:LD (IX+00),00
8137 3ADC82   NEXT:LD A,(CNTR)
813A 3D         DEC A
813B CA4981     JP Z,NEXT2
813E 32DC82     LD (CNTR),A
8141 110800     LD DE,$0008
8144 DD19       ADD IX,DE
8146 C3A180     JP ST1LP
8149 3ADD82   NEXT2:LD A,(ENDCK)
814C B7         OR A
814D CA6681     JP Z,MIDIEND
8150 C39380     JP START1
トラックの終わりの処理は簡単です。
（ＩＸ＋００）に００を書き込むだけです。
こうすることで、これ以後はこのトラックはスルーされることになります。

ＮＥＸＴは次のトラックへの処理です。
最初にトラック数を入れた（ＣＮＴＲ）の値を－１します。
結果が０なら全てのトラックを一巡したことになりますから、ＮＥＸＴ２にジャンプします。
０ではない場合にはまだ処理すべきトラックがありますから、ＩＸレジスタの値を１トラック分（８バイト）加算して、次のトラックデータテーブルアドレスをセットして巡回処理を続けます（ＳＴ１ＬＰ）。
ＳＴ１ＬＰは［第３５４回］で説明をしています。

ＮＥＸＴ２では全てのトラックの処理が終ったかどうかをチェックします。
（ＥＮＤＣＫ）の値が００のままならばすべてのトラックの処理が終っていますから、ＭＩＤＩＥＮＤにジャンプしてプログラムの終わりの処理をします（［第３５１回］）。
そうではない場合には、巡回処理の先頭に戻ります（ＳＴＡＲＴ１）。
ＳＴＡＲＴ１は［第３５４回］で説明をしています。

●テンポの設定（ＴＭＰＳＥＴ）

メタイベント　ＦＦ　５１　０３　はテンポデータの指定です。
ＴＭＰＳＥＴはテンポデータを読んで、割り込みの基準時間（ティック）を計算します。

8170 23       TMPSET:INC HL
8171 23         INC HL;pass 'length'
8172 46         LD B,(HL)
8173 23         INC HL
8174 4E         LD C,(HL);BC=TEMPO*256 cut off LSB(byte)
8175 23         INC HL
8176 23         INC HL
8177 E5         PUSH HL
8178 CD8281     CALL TMPSB
              ;
              ;timer set and int on
817B CDD381     CALL TMSB
817E E1         POP HL
817F C31881     JP NEXTDT

テンポデータは３バイトです。
可変長ではありません。
下位１バイトは無視して、上位２バイトの値をＢＣレジスタに入れて、ＴＭＰＳＢをコールし、続いてＴＭＳＢをコールします。
ＴＭＰＳＢは［第３５２回］で説明をしました。
またＴＭＳＢは［第３５３回］で説明をしました。
ティックを算出し、その値をＺ８Ｓ１８０内蔵カウンタにセットして、割り込みを許可します。
そのあと次のデータ処理（ＮＥＸＴＤＴ）にジャンプします。

●システムエクスクルーシブメッセージ（Ｆ０）の処理

システムエクスクルーシブメッセージは下のようになっています。
Ｆ０　ｎｎ　ｃｃ　ｄｄ　ｅｅ　Ｆ７
ｎｎはＭＩＤＩ機器に送るバイト数で、ｃｃ～Ｆ７のバイト数になります（この例では０４）。
最後はＦ７で終ります。
ＭＩＤＩ機器にはｎｎを除いた　Ｆ０　ｃｃ　ｄｄ　ｅｅ　Ｆ７　が送られます。

システムエクスクルーシブメッセージの処理ルーチンＣＯＤＥＦ０です。

8153 CD4B82   CODEF0:CALL MIDIOUT
8156 4E         LD C,(HL)
8157 23         INC HL
8158 CD4B82   CODEF0_2:CALL MIDIOUT
815B 0D         DEC C
815C C25881     JP NZ,CODEF0_2
815F C31881     JP NEXTDT

これでやっとＭＩＤＩ演奏プログラムの説明が完了しました。

ワンボードマイコンでＣＰ／Ｍを！［第３５６回］
２０１３．３．２５ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る