２０１３．３．２３
前へ
次へ
ホームページトップへ戻る

復活！ＣＰ／Ｍ　ワンボードマイコンでＣＰ／Ｍを！
ＣＰ／ＭがＴＫ－８０互換のワンボードマイコンの上で復活します
ＮＤ８０ＺⅢとＭＹＣＰＵ８０の上でＣＰ／Ｍが走ります！

［第３５４回］


●トラック用ワークエリアの巡回

いよいよトラック用ワークエリアの巡回チェックです。
必要な設定処理を済ませたあとは、ひたすらトラック用ワークエリアを巡回チェックします。
何をチェックするかといいますと、各トラック用ワークエリアの（ＩＸ＋０１）が００であるかどうかをぐるぐる回りながらチェックするのです。
各トラック用ワークエリアの（ＩＸ＋０２）～（ＩＸ＋０４）には時間データが書かれていて、その値は前回説明しました割込みプログラムによって、カウントダウンされていきます。
最後に０になると、（ＩＸ＋０１）に００が書き込まれます。
メインルーチンはそれを待っているのです。
時間データが最初から０のときもあります。
その場合には最初から（ＩＸ＋０１）には００が書き込まれますから、それはいきなり検出されることになります。

なにをやっているのか、いまひとつうまく説明ができません。
やっていることをひとわたり説明しますと、何をやっているのかご理解いただけると思います。

8093 DD21DE82 START1:LD IX,TPRMTOP
8097 3A0B84     LD A,(TRKNO)
809A 32DC82     LD (CNTR),A
809D AF         XOR A
809E 32DD82     LD (ENDCK),A
              ;loop
80A1 3A0B84   ST1LP:LD A,(TRKNO)
80A4 47         LD B,A
80A5 3D         DEC A
80A6 CAB680     JP Z,ST1LP1;mode0?
80A9 3ADC82     LD A,(CNTR)
80AC B8         CP B
80AD C2B680     JP NZ,ST1LP1
80B0 DD7E00     LD A,(IX+00);if mode1,pass trk1 timedata
80B3 C3C380     JP ST1LP2
80B6 3ADD82   ST1LP1:LD A,(ENDCK)
80B9 47         LD B,A
80BA DD7E00     LD A,(IX+00)
80BD F5         PUSH AF
80BE B0         OR B
80BF 32DD82     LD (ENDCK),A
80C2 F1         POP AF
80C3 B7       ST1LP2:OR A
80C4 CA3781     JP Z,NEXT
80C7 DD7E01     LD A,(IX+01)
80CA B7         OR A
80CB C23781     JP NZ,NEXT

まずは巡回チェックの前半の部分です。
トラック用ワークエリアの先頭アドレスをＩＸレジスタに入れて巡回をスタートします。
最初にトラック数を（ＣＮＴＲ）に入れます。
そして（ＥＮＤＣＫ）に００を入れておきます。
（ＥＮＤＣＫ）は全トラックデータの処理が完了したときに００のまま残ります。
プログラムの処理終了の判断に使います。

トラック数＝１はフォーマット０のときです。
もともとはフォーマット０もフォーマット１も処理に違いはなかったのですが、フォーマット１形式のＭＩＤＩファイルでトラック１の終わりに異常に長い時間が設定してあるために演奏が終了してもプログラムが終らない場合が出てきました（［第３４５回］）。
そこでフォーマット１のトラック１のみトラックの処理が完了したかどうかの判断から外す部分を追加しました。
アドレス８０Ａ９Ｈ～８０Ｂ５Ｈの部分です。
その前のアドレス８０Ａ１Ｈ～８０Ａ８Ｈでフォーマット０のときは、その部分をスキップしているのは、フォーマット０はトラック１しか存在しないからです。
トラック数が１であるのはフォーマット０のみです。フォーマット１のときはトラック数は２以上になります。

８０Ａ９Ｈ～８０Ｂ５Ｈでトラック１かどうかのチェックをしています。
レジスタＢにはその上の８０Ａ１Ｈ～８０Ａ４Ｈのところでトラック数が入ります。
（ＣＮＴＲ）の値は最初はトラック数が入りますが、トラック毎のワークエリアをチェックするたびにカウントダウンされていきます。
つまりレジスタＢと（ＣＮＴＲ）の値が一致するのは最初のトラック（トラック１）だけです。
トラック１のときには、その後ろの８０Ｂ６Ｈ～８０Ｂ２Ｈはスキップします。

８０Ｂ６Ｈ～８０Ｂ２Ｈでは、そのトラックの処理が完了したことを示す（ＩＸ＋００）の値を、全トラック処理が完了したかどうかを判断するための（ＥＮＤＣＫ）とＯＲして（ＥＮＤＣＫ）に入れます。
（ＩＸ＋００）はそのトラックの処理が完了したときに００が入れられますから（それまではＦＦＨ）、全トラックを一巡してそれでも（ＥＮＤＣＫ）が００だったらもう処理が完了していないトラックは残っていないことがわかります。
その判断からトラック１のみを外すようにしているのが、８０Ａ９Ｈ～８０Ｂ５Ｈです。

８０Ｃ３Ｈ～８０Ｃ６Ｈでは、あらためて（ＩＸ＋００）が００であるかどうかを確認して、もし００ならばこのトラックの処理は完了していますから、次のトラックの処理（ＮＥＸＴ）に移ります。
次に（ＩＸ＋０１）をチェックして、その値が００ではないときにも次のトラックの処理（ＮＥＸＴ）に移ります。
（ＩＸ＋０１）は時間データが０の時には００が入れられますが、それ以外のときには非００が入っています。
時間データは時間の経過とともに割り込みプログラムによってカウントダウンしていきます。
その時間データがまだ０になっていないということは、その時間データの次にあるＭＩＤＩイベントを処理する時ではないことを意味しています。
ですから（ＩＸ＋０１）が００ではないときには、このトラックの処理は行なわずに、次のトラックの処理に進むのです。

この次のところからがいよいよＭＩＤＩイベントデータの解読処理になりますが、そこはまた少し説明が長くなりそうですので、今回はここまでといたします。

ワンボードマイコンでＣＰ／Ｍを！［第３５４回］
２０１３．３．２３ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る