２０２３．１．６
前へ
次へ
ホームページトップへ戻る


ＰＩＣ−ＵＳＢＩＯ　ｕｓｉｎｇ　ＢＡＳＩＣ
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
ＵＳＢインターフェースを内蔵したＰＩＣを使ってＷｉｎｄｏｗｓパソコンで外部回路を制御するための各種Ｉ／Ｏ基板の製作記事です。
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜

［第１４８回］



●ＰＩＣＵＳＢＩＯ−０３（９７）Ｉ２Ｃモード（１９）送受信プログラム

［第１４４回］でマスターが送信してスレーブが受信するプログラムを作ってテストしました。
［第１４６回］ではその逆のプログラム、スレーブが送信してマスターが受信するプログラムを作ってテストをしました。
今回はその２組のプログラムをマスター側とスレーブ側でそれぞれ結合してそれぞれを１本のプログラムにしてテストをしてみました。
最も単純な考え方としてはマスター側もスレーブ側もそれぞれ２本のプログラムを単純にくっつけて１本にした上で最初のプログラムと次のプログラムの間にＳＴＯＰ文を置くという簡便な方法もあります。
そのようにしておいてプログラムを実行すると前半部分が実行されたあとＳＴＯＰ文でブレークします。
そのあとＳＴＯＰ文の次の行に対してＧＯＴＯ文を実行すれば後半部分が実行されます。
実際にそのようにして試してみてうまく動作することを確認しました。
しかしそれでは実用的ではありません。
途中のＳＴＯＰ文は省いて最初から最後まで１本のプログラムにしてそれで動作するようにすべきです。
そこでＳＴＯＰ文を省いて実行してみたところやっぱり後半部分に入ったところで止まってしまいました。
やはり前半と後半のつなぎの部分には工夫が必要でした。

下は最終的に正しく最後まで動作することを確認したプログラムです。
プログラムが今までより長くなって１画面では表示できませんのでテキストで示します。
まずはマスター側のプログラムです。 
   10 picout TRISB,$ff
   20 picout SSPCON1,0
   30 picout SSPSTAT,$80
   40 picout SSPCON1,$28
   50 picout SSPADD,$77
   60 picout SSPCON2,1:'START
   70 picout SSPBUF,$00:'address write
   80 if and(picin(SSPSTAT),1)=1 goto 80
   90 picout SSPBUF,$41
  100 if and(picin(SSPSTAT),1)=1 goto 100
  110 picout SSPBUF,$42
  120 if and(picin(SSPSTAT),1)=1 goto 120
  130 picout SSPCON2,4:'STOP
  140 print hex$(picin(SSPSTAT)):'dummy
  150 print hex$(picin(SSPCON1)):'dummy
  160 print hex$(picin(SSPCON2)):'dummy
  170 picout SSPCON2,$01:'start
  180 picout SSPBUF,$01:'address read
  190 if and(picin(SSPSTAT),1)=1 goto 190
  200 picout SSPCON2,$08:'receive enable
  210 if and(picin(SSPSTAT),1)=0 goto 210
  220 print hex$(picin(SSPBUF))
  230 picout SSPCON2,$10:'ack
  240 picout SSPCON2,$08
  250 if and(picin(SSPSTAT),1)=0 goto 250
  260 print hex$(picin(SSPBUF))
  270 picout SSPCON2,$30:'nack
  280 picout SSPCON2,4:'STOP

１３０行のＳＴＯＰはＳＴＯＰ文ではありません。
前半のプログラムの最後にマスターが発行するＳＴＯＰコンディションです。
１０行からその１３０行までがマスターが送信してスレーブがそれを受信するモードでのマスター側のプログラムです。
この部分は［第１４４回］のマスター側のプログラムと同じです。
ただしもとのプログラムに２０行を追加してあります（このことについては前回の「ＷＣＯＬ」のところを参照してください）。
プログラムの後半部分は１７０行から２８０行までです。
ここはスレーブが送信してマスターが受信するモードのマスター側のプログラムです。
この部分は［第１４６回］のマスター側のプログラムと同じです。
ただしもとのプログラムの初期設定部分（１０行〜５０行）は不要なので省いてあります。
今回のプログラムの１９０行はもとのプログラムにはありませんがスレーブ側のタイミングの遅れを考慮して念のために入れて有ります。
１８０行のスレーブアドレスの送信が完了してＢＦフラグがクリアされるまで待ちます。
もうひとつ追加しているところがあります。
１４０行〜１６０行です。
ここがないとスレーブ側のプログラムが後半に入ったところでこけてしまいます。
スレーブ側のプログラムで、ＳＴＯＰコンディションを確認してから次のＳＴＡＲＴコンディション、スレーブアドレスの受信をするところまでが間に合わないときがあります。
ＳＴＯＰコンディションによってＣＫＰビットがクリアされてしまいクロックストレッチングが解除されてしまうためだと思うのですが、それ以後にスレーブ側で実行が遅れると受信エラーになってしまいます。
ＳＴＯＰコンディションを使わないでＲＳＥＮ（リピーテッドスタートコンディション、ＳＳＰＣＯＮ２レジスタのｂｉｔ１）を使えばよいかと思ったのですがうまくいきませんでした（使い方に問題があったのかもしれません）。
簡便な方法としてダミー命令で時間を稼ぐことにしました。
それが１４０行〜１６０行です。
ｐｉｃｉｎ関数は実行時間がかかります（約６〜８ｍｓｅｃ、［第１２９回］参照］）。
それを利用しました。
こんなに入れなくてもよいかもしれませんが念のためです。
これで２０〜２５ｍｓｅｃほどの遅延になります。
これを入れることで正常に動作することが確認できました。

次はスレーブ側のプログラムです。
   10 picout TRISB,$ff
   20 picout SSPCON1,0
   30 picout SSPSTAT,$80
   40 picout SSPCON1,$26
   50 picout SSPCON2,$81
   60 if and(picin(SSPSTAT),1)=0 goto 60
   70 print hex$(picin(SSPBUF))
   80 picout SSPCON1,$36:'CKP=1
   90 if and(picin(SSPSTAT),1)=0 goto 90
  100 print hex$(picin(SSPBUF))
  110 picout SSPCON1,$36:'CKP=1
  120 if and(picin(SSPSTAT),1)=0 goto 120
  130 print hex$(picin(SSPBUF))
  140 picout SSPCON1,$36:'CKP=1
  150 if and(picin(SSPSTAT),$10)=0   goto 150
  160 print "stop detect"
  170 if and(picin(SSPSTAT),1)=0 goto 170
  180 print hex$(picin(SSPBUF)):'address
  190 picout SSPBUF,$61:'a
  200 picout SSPCON1,$36:'CKP=1
  210 if and(picin(SSPCON1),$10)=$10 goto 210
  220 picout SSPBUF,$62:'b
  230 picout SSPCON1,$36:'CKP=1
  240 if and(picin(SSPSTAT),1)=1 goto 240
  250 if and(picin(SSPSTAT),$10)=0 goto 250:'stop

１０行から１６０行までがマスターが送信してスレーブがそれを受信するモードでのスレーブ側のプログラムです。
この部分は［第１４４回］のスレーブ側のプログラムと同じです。
ただしもとのプログラムの４０行で＄３６になっていたところを＄２６にしてあります。
ここは＄３６にしなくてもよいことがわかりましたのでそのようにしてあります。
１６０行はもとのプログラムではＳＴＯＰ文でしたがここはＰＲＩＮＴ文に変更しました。
プログラムの後半部分は１７０行から２５０行までです。
ここはスレーブが送信してマスターが受信するモードのスレーブ側のプログラムです。
この部分は［第１４６回］のスレーブ側のプログラムと同じです。
ただしもとのプログラムの初期設定部分（１０行〜５０行）は不要なので省いてあります。
今回のプログラムは最後のところに２４０行があります（ここで送信完了を見ています）がこれは不要だったと思います。

プログラムを実行しました。

左側（マスター側）の画面で実行後に表示されている３バイトのデータ（８８、２８、００）は１４０行〜１６０行のダミー命令での表示です。
その下の６１（’ａ’）と６２（’ｂ’）がスレーブから送信されたデータです。
右側（スレーブ側）の最初の’００’はゼネラルコールアドレスで最後の’０１’はスレーブアドレス＋Ｒ／Ｗ（＝１）です。
４１（’Ａ’）と４２（’Ｂ’）がマスターから送信されたデータです。

上で２４０行は「多分不要だったと思います」と書きました。
ただ思っただけで済ませてはいけません。
念のために２４０行をコメント文にして実行してみました。

同じ結果になりました。

ＰＩＣ−ＵＳＢＩＯ　ｕｓｉｎｇ　ＢＡＳＩＣ［第１４８回］
２０２３．１．６ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る