標準ＴＴＬだけ（！）でCPUをつくろう！（組立てキットです！）
(ホントは７４ＨＣ、ＣＭＯＳなんだけど…）
［第６４２回］

●ＰＩＣ１８Ｆ１４Ｋ５０のＨＩＤプログラム（その初期設定部分その３）

このところ多忙で、ほんの少しずつしか書く時間がありません。
気長にお付き合いをお願いいたします。

今回もＰＩＣ１８Ｆ１４Ｋ５０を使ったＨＩＤプログラムの初期設定部分の続きです。

;
	call setbd0
	call setbd1
	call setbd2
;

エンドポイントＥＰ０（ＯＵＴ）ＤＡＴＡ０、ＥＰ０（ＯＵＴ）ＤＡＴＡ１、ＥＰ０（ＩＮ）をＰＩＣ１８Ｆ１４Ｋ５０内蔵のＵＳＢＳＩＥ（Ｓｅｒｉａｌ　Ｉｎｔｅｒｆａｃｅ　Ｅｎｇｉｎｅ）が使えるように設定をします。
それぞれサブルーチンｓｅｔｂｄ０、ｓｅｔｂｄ１、ｓｅｔｂｄ２をｃａｌｌします。

その各サブルーチンです。

;
;ep0 out data0(even)
setbd0
	lfsr 1,203
	movlw 02;address high
	movwf POSTDEC1
	movlw 20;address low
	movwf POSTDEC1
	movlw 08;bytes
	movwf POSTDEC1
	movlw 88;STAS(even)*********************
	movwf POSTDEC1
	return
;ep0 out data1(odd)
setbd1
	lfsr 1,207
	movlw 02;address high
	movwf POSTDEC1
	movlw 28;address low
	movwf POSTDEC1
	movlw 08;bytes
	movwf POSTDEC1
	movlw 0c8;STAS(odd)
	movwf INDF1
	return
;
;
;***** set DEVICE DESCRIPTOR *****
;
;set DEVICE DESCRIPTOR top 8 bytes
;
setbd2		
	lfsr 1,230
	;
	movlw 12;size(bytes)
	movwf POSTINC1
	movlw 01;type(DEVUCE DESCRIPTOR)
	movwf POSTINC1
	movlw 00;USB version 02.00(Low)
	movwf POSTINC1
	movlw 02;(High)
	movwf POSTINC1
	movlw 00;HID class
	movwf POSTINC1
	movlw 00;SUB class
	movwf POSTINC1
	movlw 00;protocol code
	movwf POSTINC1
	movlw 08;max packet size of EP0
	movwf POSTINC1
	;
	call setbd2odd
	movlw 1
	movwf bd2mk;=1
	return
;
;
setbd2odd
	lfsr 1,20b
	movlw 02;address high
	movwf POSTDEC1
	movlw 30;
	movwf POSTDEC1
	movlw 8;bytes
	movwf POSTDEC1	
	movlw 0c8
	movwf INDF1
	return
;

ここは［第６３９回］で説明しました各エンドポイントのＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲ　ＴＡＢＬＥに所定のデータを書き込むためのルーチンです。
ＥＰ０（ＯＵＴ）ＤＡＴＡ０のテーブルアドレスは２００〜２０３、ＥＰ０（ＯＵＴ）ＤＡＴＡ１は２０４〜２０７です。
ＥＰ０（ＯＵＴ）ＤＡＴＡ０のバッファアドレスは２２０〜２２７、ＥＰ０（ＯＵＴ）ＤＡＴＡ１のバッファアドレスは２２８〜２２Ｆです。
ＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲ　ＴＡＢＬＥはエンドポイント毎にアドレスが決まっていますが、バッファそのものは任意のアドレスに置くことができます（といってもアドレス２００〜２ＦＦの範囲で未使用のところに限ります）。

後ろから書いているのは、先頭のＢＤｎＳＴＡＴに値を書き込むことでＳＩＥが直ちにそのエンドポイントに対してアクティブに働くようになりますから、その前に必要なパラメータ（バッファアドレス、バッファサイズ）をセットしておくためです。

ＥＰ０（ＯＵＴ）に対しての設定は簡単ですがＥＰ０（ＩＮ）はちょっと様子が異なります。
ＥＰ０（ＯＵＴ）は、ＵＳＢホストコントローラから見て”ＯＵＴ”ですから、ＰＩＣ１８Ｆ１４Ｋ５０は”ＩＮ”になります。
送られてくるデータ（コマンド）を受け取れるようにすればよいだけですから設定は簡単です。
それに対してＥＰ０（ＩＮ）はＰＩＣ１８Ｆ１４Ｋ５０からＵＳＢホストコントローラにデータを送信しなければなりません。
ＵＳＢホストコントローラが「送信要求」を送ってきたらすぐにデータを送信できるように、データバッファに送信データをセットしたうえでＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲ　ＴＡＢＬＥに必要な値をセットしなければなりません。

ＥＰ０（ＩＮ）のデータバッファはアドレス２３０〜２３７です。
最初にこのバッファアドレスに書いておくデータは、ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲの先頭の８バイトです。
ＵＳＢデバイスを接続したときに、ＵＳＢホストコントローラがそのＵＳＢデバイスに最初に送る送信要求コマンドは、ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲの送信要求だからです。

ここはＨＩＤデバイスのデバイスデスクリプタの書き方にしたがって値を設定します。
デスクリプタの先頭にはそのデスクリプタのバイト数を書きます。１２は１６進数です。
デバイスデスクリプタは１８バイトです。ここではその最初の８バイトをセットします。
次はデスクリプタのタイプを書きます。デバイスデスクリプタは０１です。
その次２バイトはＵＳＢのバージョンを書きます。２．０ですから、ここは００　０２にします。
その次はクラスコードです。
ＨＩＤの場合ここは００でよいようです。
最後にエンドポイントＥＰ０のパケットサイズを指定します。
ここは８（バイト）にします。

そのようにバッファに値をセットしてから、ＥＰ０（ＩＮ）のＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲ　ＴＡＢＬＥ（アドレス２０８〜２０Ｂ）をセットします。
セットするためのサブルーチンｓｅｔｂｄ２ｏｄｄをＣＡＬＬします。

サブルーチンｓｅｔｂｄ２ｏｄｄでは、バッファアドレス２３０と、バッファサイズ８（バイト）を指定したあと、最後にＢＤｎＳＴＡＴに値を設定します。
最初のデバイスデスクリプタの送信は、ＵＳＢホストコントローラの送信要求コマンド（ホストからのコマンドはＤＡＴＡ０ではじまります）に対する返信ということになりますから、ＤＡＴＡ１で送信します（ということのようです）。
そこで、このバッファデータはＤＡＴＡ１で送る、ということをＳＩＥに知らせるために、ＢＤｎＳＴＡＴにはＣ８をセットします。
ＤＡＴＡ０の場合にはここは８８をセットします。
ＢＤｎＳＴＡＴについては［第４８２回］にｄａｔａｓｈｅｅｔがあります。
ＰＩＣ１８Ｆ４５５０のものですがＰＩＣ１８Ｆ１４Ｋ５０でも同じです。
ビット６とビット３が関係します。
なおＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲについては、［第６３７回］と［第６３８回］もあわせてお読みください。

ｓｅｔｂｄ２ｏｄｄをＣＡＬＬしたあと、ワークレジスタｂｄ２ｍｋに１をセットしています。そのようにする理由については、もう少し先になってから説明をいたします。
２０１０．１０．２０ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る