２０１２．２．１６
前へ
次へ
ホームページトップへ戻る

復活！ＣＰ／Ｍ　ワンボードマイコンでＣＰ／Ｍを！
ＣＰ／ＭがＴＫ－８０互換のワンボードマイコンの上で復活します
ＮＤ８０ＺⅢとＭＹＣＰＵ８０の上でＣＰ／Ｍが走ります！

［第３５回］

●ＣＰ／Ｍソースプログラムの再変更

［第３２回］で、とりあえずのＣＰ／Ｍソースプログラムの修正作業は完了です、と書きましたが、いろいろ作業を進めておりますと、だんだんと理解が深まってきて、さらに直したいところなどが出て来てしまいます。

とは言いましても、今回これから説明しますところは、変更しなくても実行には影響はありません。
さらに言えば、もともと仮のＲＡＭディスクでのテストですし、どうせメモリ増設基板を接続することになりましたら、いやでも再変更しなければなりませんから、そのままにしておいても、別にどうということはありません。

しかし。
そうだとしても、やっぱりこのままにしておくのは、ちょっと気が引けます。

気になって、直しておきたいと思いますのは、ＢＩＯＳの先頭部分に置いた、ディスクパラメータの位置のことなのです。
下は［第３２回］でお見せしたリストの先頭部分です。

;*************** BIOS DATA AREA ******************************
;
DIRBF EQU 0B800H;128bytes
;
CSV00 EQU 0B880H;8bytes 
ALV00 EQU 0B888H;3bytes
;
;   DISK PARAMETER BASE
;
DPBASE: 
;
;drive No.0 (a drive)
        DEFW    0               ;XLATE
        DEFW    0               ;scratch1
        DEFW    0               ;scratch2
        DEFW    0               ;scratch3
        DEFW    DIRBF           ;address of dirbf.
        DEFW    DPTOP           ;address of disk parameter block.
        DEFW    CSV00           ;address of check vector.
        DEFW    ALV00           ;address of allocation vector (bit map).
;
;
DPTOP:DEFW      16              ;sectors per track from bios.
        DEFB    2               ;block shift.sector in a block 128*2^n
        DEFB    3               ;block mask.sector no. in a block - 1
        DEFB    0               ;extent mask.
        DEFW    23              ;disk size (number of blocks-1).
        DEFW    31              ;directory size.(max file name no.-1)
        DEFW    0C0H            ;storage for first bytes of bit map (dir space used).
        DEFW    8               ;check sum vector size
        DEFW    0               ;offset. first usable track number.
;
;**************************************************************
;*
;*        B I O S   J U M P   T A B L E
;*
;**************************************************************
;
BOOT:   JP      BOOTJ
WBOOT:  JP      WBOOTJ
CONST:  JP      CONSTJ
CONIN:  JP      CONINJ
CONOUT: JP      CONOUTJ
LIST:   JP      LISTJ
PUNCH:  JP      PUNCHJ
READER: JP      READERJ
HOME:   JP      HOMEJ
SELDSK: JP      SELDSKJ
SETTRK: JP      SETTRKJ
SETSEC: JP      SETSECJ
SETDMA: JP      SETDMAJ
READ:   JP      READJ
WRITE:  JP      WRITEJ
PRSTAT: JP      PRSTATJ
SECTRN: JP      SECTRNJ
;
;BIOS ROUTINE
;

ＤＩＳＫ　ＰＡＲＡＭＥＴＥＲが、ＢＩＯＳのジャンプテーブルの前にあります。
いろいろとやっておりますうちにわかってきたことなのですが、このデータはＣＰ／Ｍの暗黙のルールとして、ＢＩＯＳジャンプテーブルの後に置くもののようです。
そこで、そっくりそのまま移動して下のようにします。

;*************** BIOS DATA AREA ******************************
;
DIRBF EQU 0B800H;128bytes
;
CSV00 EQU 0B880H;8bytes 
ALV00 EQU 0B888H;3bytes
;
;**************************************************************
;*
;*        B I O S   J U M P   T A B L E
;*
;**************************************************************
;
BOOT:   JP      BOOTJ
WBOOT:  JP      WBOOTJ
CONST:  JP      CONSTJ
CONIN:  JP      CONINJ
CONOUT: JP      CONOUTJ
LIST:   JP      LISTJ
PUNCH:  JP      PUNCHJ
READER: JP      READERJ
HOME:   JP      HOMEJ
SELDSK: JP      SELDSKJ
SETTRK: JP      SETTRKJ
SETSEC: JP      SETSECJ
SETDMA: JP      SETDMAJ
READ:   JP      READJ
WRITE:  JP      WRITEJ
PRSTAT: JP      PRSTATJ
SECTRN: JP      SECTRNJ
;
;   DISK PARAMETER BASE
;
DPBASE: 
;
;drive No.0 (a drive)
        DEFW    0               ;XLATE
        DEFW    0               ;scratch1
        DEFW    0               ;scratch2
        DEFW    0               ;scratch3
        DEFW    DIRBF           ;address of dirbf.
        DEFW    DPTOP           ;address of disk parameter block.
        DEFW    CSV00           ;address of check vector.
        DEFW    ALV00           ;address of allocation vector (bit map).
;
;
DPTOP:DEFW      16              ;sectors per track from bios.
        DEFB    2               ;block shift.sector in a block 128*2^n
        DEFB    3               ;block mask.sector no. in a block - 1
        DEFB    0               ;extent mask.
        DEFW    23              ;disk size (number of blocks-1).
        DEFW    31              ;directory size.(max file name no.-1)
        DEFW    0C0H            ;storage for first bytes of bit map (dir space used).
        DEFW    8               ;check sum vector size
        DEFW    0               ;offset. first usable track number.
;
;BIOS ROUTINE
;

ＢＩＯＳジャンプテーブルの置かれているアドレスはどこでもよい、というものではないらしく、ＢＩＯＳジャンプテーブルの先頭アドレス（ＢＯＯＴ：のアドレス）が××００Ｈになるように配置するもののようです。
ソースプログラムでは、ＣＣＰ、ＢＤＯＳに続いて記述するのですが、このときディスクパラメータがＢＩＯＳジャンプテーブルの前にあると、ジャンプテーブルアドレスを××００Ｈに固定しにくくなります。
もともとジャンプテーブルはその名の通り、各処理プログラムへのジャンプ命令を集めたものですから、ＢＩＯＳの先頭に置くのが理にかなっています。

ということで、せっかく［第３２回］でコピーしてＣＰ／Ｍソースプログラムに貼り付けていただいたのですが、上のリストのようにディスクパラメータ部分をＢＩＯＳジャンプテーブルの後に変更していただきますようお願いいたします。

念の為に、変更後のＢＩＯＳルーチン全体のリスト（［第３２回］のリストを、ディスクパラーメータ部分のみ切り取って、ＢＩＯＳジャンプテーブルの後に貼り付けたもの）を下に表示しておきます。

;*************** BIOS DATA AREA ******************************
;
DIRBF EQU 0B800H;128bytes
;
CSV00 EQU 0B880H;8bytes 
ALV00 EQU 0B888H;3bytes
;
;**************************************************************
;*
;*        B I O S   J U M P   T A B L E
;*
;**************************************************************
;
BOOT:   JP      BOOTJ
WBOOT:  JP      WBOOTJ
CONST:  JP      CONSTJ
CONIN:  JP      CONINJ
CONOUT: JP      CONOUTJ
LIST:   JP      LISTJ
PUNCH:  JP      PUNCHJ
READER: JP      READERJ
HOME:   JP      HOMEJ
SELDSK: JP      SELDSKJ
SETTRK: JP      SETTRKJ
SETSEC: JP      SETSECJ
SETDMA: JP      SETDMAJ
READ:   JP      READJ
WRITE:  JP      WRITEJ
PRSTAT: JP      PRSTATJ
SECTRN: JP      SECTRNJ
;
;   DISK PARAMETER BASE
;
DPBASE: 
;
;drive No.0 (a drive)
        DEFW    0               ;XLATE
        DEFW    0               ;scratch1
        DEFW    0               ;scratch2
        DEFW    0               ;scratch3
        DEFW    DIRBF           ;address of dirbf.
        DEFW    DPTOP           ;address of disk parameter block.
        DEFW    CSV00           ;address of check vector.
        DEFW    ALV00           ;address of allocation vector (bit map).
;
;
DPTOP:DEFW      16              ;sectors per track from bios.
        DEFB    2               ;block shift.sector in a block 128*2^n
        DEFB    3               ;block mask.sector no. in a block - 1
        DEFB    0               ;extent mask.
        DEFW    23              ;disk size (number of blocks-1).
        DEFW    31              ;directory size.(max file name no.-1)
        DEFW    0C0H            ;storage for first bytes of bit map (dir space used).
        DEFW    8               ;check sum vector size
        DEFW    0               ;offset. first usable track number.
;
;BIOS ROUTINE
;
;zb3routine
;
ADISP EQU 1015H
ZREENT EQU 1033H
SOUT EQU 10ABH
SIN EQU 10AEH
;
TRKADRS EQU 0BB00H
SCTADRS EQU 0BB02H
DMAADRS EQU 0BB04H
DRVNO   EQU 0BB06H
DISKTOP EQU 8800H
;
SETENTRY:LD HL,REENT
        LD A,0C3H
LD (HL),A
        INC HL
        LD DE,SETEN2
        LD (HL),E
        INC HL
        LD (HL),D
SETEN2:LD HL,IOBYTE
        XOR A
        LD (HL),A
        INC HL
        LD (HL),A
        INC HL
        LD A,0C3H
        LD (HL),A
        INC HL
        LD DE,FBASE
        LD (HL),E
        INC HL
        LD (HL),D
        JP CBASE
;
BOOTJ:XOR A
        LD (IOBYTE),A
        JP      CBASE
;
WBOOTJ: LD A,(IOBYTE)
        LD C,A
        JP      CBASE
;
;CONSOLE STATUS
;
CONSTJ:LD A,07
        CALL SOUT
        CALL SIN
        CP 20H
        RET NZ
        XOR A
        RET
;
;CONSOLE INPUT
;
CONINJ: LD A,5;1chr IN,nodp
        CALL SOUT
        CALL SIN
        RET
;
;CONSOLE OUT
;
CONOUTJ:LD A,C
        CP 0AH;12.1.8
        JP NC,ADISP ;11.12.29
        XOR A
        RET
;
;PRINTER OUT
;
LISTJ:  RET
;
;PUNCHER OUT
;
PUNCHJ: RET
;
;READER IN
;
READERJ:        RET;JP  0
;
;SEEK HOME POSITION
;
HOMEJ:  LD HL,DISKTOP
        LD (TRKADRS),HL
        LD (SCTADRS),HL
        XOR A
        RET
;
;SELECT DRIVE PARAMETER SET
;
SELDSKJ:LD HL,DPBASE
        LD A,C
        LD (DRVNO),A
        RET
;
;SET TRKADRS
;
SETTRKJ:LD HL,DISKTOP
        LD DE,800H
        INC C
STTRK1: DEC C
        JP Z,STTRK9
        ADD HL,DE
        JP STTRK1
STTRK9:LD (TRKADRS),HL
        XOR A
        RET     
;
;SET SCTADRS
;
SETSECJ:LD HL,(TRKADRS)
        LD DE,80H
        INC C
STSCT1: DEC C
        JP Z,STSCT9
        ADD HL,DE
        JP STSCT1
STSCT9:LD (SCTADRS),HL
        XOR A
        RET     
;
;SET DMAADRS
;
SETDMAJ:LD H,B
        LD L,C
        LD (DMAADRS),HL
        XOR A
        RET
;
;READ SECTOR
;
READJ:LD HL,(DMAADRS)
        EX DE,HL
        LD HL,(SCTADRS)
READJ1: LD C,80H
READJ2:LD A,(HL)
        LD (DE),A
        INC HL
        INC DE
        DEC C
        JP NZ,READJ2
        XOR A
        RET
;
;WRITE SECTOR
;
WRITEJ: LD HL,(SCTADRS)
        EX DE,HL
        LD HL,(DMAADRS)
        JP READJ1
;
;PRINTER STATUS
;
PRSTATJ:        RET
;
;sector translator
;
SECTRNJ:LD L,C
        LD H,B
        RET;
;
;*
;******************   E N D   O F   C P / M   *****************
;*
END;

そのように変更していただいたら、ＣＰＭ２２Ｅ．ＴＸＴという名前で保存してください。
このファイルを［第３４回］で説明しましたように、Ｚ８０アセンブラＺＡＳＭ１．６４でアセンブルします。



●ｃｐｍ２２．ｚ８０のバグ

上の作業に関連していろいろ調べておりましたら、今回の作業のもとになっております、ｃｐｍ２２．ｚ８０にバグがあるのに気が付きました。

上で説明をしましたように、ＢＩＯＳジャンプテーブルは、ＢＤＯＳの後に続いて記述していますが、そのアドレスは××００Ｈにするのが、ＣＰ／Ｍの暗黙のルールのようです。
そのためには、ＢＤＯＳとＢＩＯＳの間にダミーエリアを置いてそこでアドレスを調整するという方法が考えられます。

ＢＤＯＳとＢＩＯＳの間にある、よくわからないエリアが、そのダミーデータのようです（「Ｅｘｔｒａ　ｓｐａｃｅ？」とコメントされている部分）。



ここでは４バイトのスペースがそれに相当するように思われます。
その上のＣＫＳＵＭＴＢＬ：は１６バイトあって、それにはその上のコメントで、ディレクトリバッファのチェックサム用エリアだと説明してあります。
そして接続可能な最大ドライブ数（１６台）のそれぞれ用に１バイトなので１６バイトである、と書かれています。

本当か？
それはおかしいのでは？
と疑問を感じたのがそもそものきっかけでした。

ディレクトリのチェックサムとしては［第３３回］で説明をいたしました。
ＣＳＶがそれです。
ディスクごとに１バイトではなくて、ディレクトリのセクタごとに１バイトが必要です（そのはずです）。
それなら、上で書かれている説明は間違っていることになります。

そしてもしもこのエリアが各ドライブのＣＳＶエリアのアドレスを格納するためのものだったとすれば、各ドライブに２バイト必要ですから、１６バイトでは足りません。
するとここは、一体何のためのエリアなのでしょうか？
それを探るために、ＣＫＳＵＭＴＢＬで検索してみました。
その結果意外なことがわかりました。


検索の結果、ＣＫＳＵＭＴＢＬを参照しているのは、下のＣＨＥＣＫＤＩＲルーチンの中の２２０１行と２２１０行の２ヶ所のみであることがわかりました。



これを見ると、やはりアドレスの格納用に使われているようですから、２バイトです。
そしてＣＫＳＵＭＴＢＬに値を設定しているのは、下の１ヶ所のみです。



ＴＲＫＳＥＣというルーチンは、ディレクトリアクセス以外でも使われているようですが、とにかくディレクトリを読んだときに、そのディレクトリがあるセクタナンバー（０から始まる連番か？）がＣＫＳＵＭＴＢＬに入るようです。
さきほどのルーチンでは、その値とＡＬＬＯＣ１の値とを比較することで、全ディレクトリのチェックサムが完了したかどうかを確認しているようです。
ＡＬＬＯＣ１については、［第１３回］で説明をいたしました。ＣＫＶＳの誤記のようです。
ＣＫＶＳにはディレクトリのセクタ数が入ります（［第３３回］）。

ところで上記のＣＫＳＵＭＴＢＬに関わるルーチンのどこにも、ＣＫＳＵＭＴＢＬの後方のアドレスを使うところは見当たりませんでした。
ということは、ＣＫＳＵＭＴＢＬとしては２バイトのみが使われているだけ、ということになます。
つまり、そのところは、下のように書くのが正しいと思います。



ＣＫＳＵＭＴＢＬ：の２バイトの後にあるエリアは、上の方で書きましたように、ＢＩＯＳジャンプテーブルの開始アドレスを××００Ｈにするためのダミーだと思います。

なんだ。こんなことぐらいなら、バグというほどのものでもないじゃないか。
ええ。
これ位のことなら、バグではありません。

じつは。
バグは、このＣＫＳＵＭＴＢＬに関係する、別のところで偶然みつけてしまったのです。
上のところでお見せした、ＣＫＳＵＭＴＢＬを参照しているこちらのルーチンを見ておりましたら、２２０７行でＣＡＬＬしておりますＣＨＥＣＫＳＵＭルーチンではどんな計算をしているのだろう？
という興味がわいてきたのです。
そこで、そのＣＨＥＣＫＳＵＭルーチンを見てみました。
そうしましたら、そこにバグがあったのです。

これがＣＨＥＣＫＳＵＭルーチンです。
ここのどこにバグがあるか、おわかりになりますでしょうか？ 

                     	;
                      	;   Compute the check-sum for the directory buffer. Return
                      	; integer sum in (A).
                      	;
  C8FA  0E80          	CHECKSUM: LD	C,128		;length of buffer.
  C8FC  2AC0D1        		LD	HL,(DIRBUF)	;get its location.
  C8FF  AF            		XOR	A		;clear summation byte.
  C900  C600          	CHKSUM1:ADD	A,M		;and compute sum ignoring carries.
  C902  23            		INC	HL
  C903  0D            		DEC	C
  C904  C200C9        		JP	NZ,CHKSUM1
  C907  C9            		RET

あ。
これは次回までの宿題ということにいたしましょう。

ワンボードマイコンでＣＰ／Ｍを！［第３５回］
２０１２．２．１６ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る