２０１２．８．３
前へ
次へ
ホームページトップへ戻る

復活！ＣＰ／Ｍ　ワンボードマイコンでＣＰ／Ｍを！
ＣＰ／ＭがＴＫ－８０互換のワンボードマイコンの上で復活します
ＮＤ８０ＺⅢとＭＹＣＰＵ８０の上でＣＰ／Ｍが走ります！

［第１８８回］


●ＲＴ＠コマンド（ＣＰ／Ｍ互換ＤＯＳのための変更その３）

今回はＣＰ／Ｍ互換ＤＯＳのための変更を行なったブレーク処理プログラムについての説明の最終回です。
ＦＦコード（ＲＳＴ７）を利用してブレークしたあと、そのブレークポイントからプログラムの続きの実行を再開するためのコマンドがＲＴコマンドです。
ＲＴコマンドについて説明をする前に、ＢＰコマンドについて説明を補足しておきます（ＢＰコマンドについては［第１８６回］を参照）。

ブレークポイントを設定するためのＢＰコマンドはフルＲＡＭに対応するようにプログラム変更を行ないましたが、ＤＭ＠コマンドやＣＭ＠コマンドのように、対象になるメモリアドレスがフルＲＡＭの００００Ｈ～７ＦＦＦＨである場合の＠記号を使うようにはしませんでした。
それはＢＰコマンドの特殊性からきています。
ＢＰコマンドはブレークアドレスのマシン語命令コードをＦＦ（ＲＳＴ７）で置き換えるためのコマンドです。
アドレス００００Ｈ～７ＦＦＦＨがもしもＲＯＭであった場合、その行為そのものが意味をもちません（当然ブレークすることはできません）。

つまりＢＰコマンドの場合には、ブレークアドレスとして００００Ｈ～７ＦＦＦＨが指定されたならば、それはフルＲＡＭ構成を選択していると考えればよいことになります。
ですからわざわざＢＰ＠とする必要はありません。

ＲＴコマンドの場合はどうでしょうか。
ＲＴコマンドを入力する時点では、００００Ｈ～７ＦＦＦＨはＲＯＭが選択されています。
ブレークしたアドレスから実行を再開するのですが、そのアドレスが００００Ｈ～７ＦＦＦＨの範囲でしたら、当然フルＲＡＭ構成を選択することになります。
では８０００Ｈ以降のアドレスならば、フルＲＡＭなのでしょうか？
それともＲＯＭのままなのでしょうか？

これはアドレスからだけでは決められません。
むむむ。
今気がつきました。
ブレークしたときにフルＲＡＭかＲＯＭかいずれが選択されているかという情報を保存しておけば、ＲＴコマンド入力時にその情報から同じ状態に戻すことができますね。
いずれ時間ができたら、そのように考えてみましょう。

今はＲＴコマンドならば００００Ｈ～７ＦＦＦＨはＲＯＭ、ＲＴ＠コマンドを使ったならばフルＲＡＭを選択する、というプログラムになっています。
下がそのように変更を行なったあとのＲＴプログラムのリストです。
変更前のリストは［第１８４回］にあります。
プログラムの変更を行なったために、アドレスが少し変わっています。

              ;;;
              ;;;RETURN
1B98 1A       RT:LD A,(DE)
1B99 32D1F2   LD (RAMCK),A
1B9C 2100ED   LD HL,STCWK
1B9F 1100F5   LD DE,STC
1BA2 010003   LD BC,$0300
1BA5 EDB0     LDIR
1BA7 3184F0   RT2:LD SP,HLBF2   
1BAA E1       POP HL
1BAB D1       POP DE
1BAC C1       POP BC
1BAD D9       EXX
1BAE F1       POP AF
1BAF 08       EX AF,AF'
1BB0 E1       POP HL
1BB1 D1       POP DE
1BB2 C1       POP BC
1BB3 F1       POP AF
1BB4 FDE1     POP IY
1BB6 DDE1     POP IX
1BB8 F5       PUSH AF
1BB9 3AD1F2   LD A,(RAMCK)
1BBC FE40     CP 40;@
1BBE CA39D2   JP Z,RTRAM
1BC1 F1       POP AF
1BC2 ED7B99F0 LD SP,(SPBF)
1BC6 228CF0   LD (HLBF1),HL   
1BC9 2A9BF0   LD HL,(PCL)
1BCC E5       PUSH HL
1BCD 2A8CF0   LD HL,(HLBF1)   
1BD0 C9       RET
              ;;;

変更前のＲＴプログラムは、エントリ部分でＺＢ３ＢＡＳＩＣのもとになったシステムのための処理をしているところ（［第１８４回］のリストのアドレス１ＢＡＡＨ～１ＢＢ９Ｈ）が残ったままになっていましたので、その部分は今回の変更と同時に削除しました。
ＣＰ／Ｍ互換ＤＯＳのための変更は、上のリストの１Ｂ９８Ｈ～１Ｂ９ＢＨと、１ＢＢ９Ｈ～１ＢＣ０Ｈの部分です。
ＲＴの後に’＠’がついていたら、ＢＩＯＳのＲＴＲＡＭへジャンプします。

●ＢＩＯＳのＲＴＲＡＭルーチン

下はＣＰ／Ｍ互換ＤＯＳのＢＩＯＳプログラムの先頭のジャンプテーブルです。
アドレスＤ２３９ＨにＲＴＲＡＭルーチンへのジャンプ命令があります。

              ;
              	ORG $D200
              ;
D200 C377D2   	JP SETENTRY;coldboot
D203 C37ED2   BOOT:JP WBOOTJ
D206 C312D3   	JP CONSTJ
D209 C334D3   	JP CONINJ
D20C C354D3   	JP CONOUTJ
D20F C374D3   	JP LISTJ
D212 C375D3   	JP PUNCHJ
D215 C387D3   	JP READERJ
D218 C3A6D3   	JP HOMEJ
D21B C3B1D3   	JP SELDSKJ
D21E C3CDD3   	JP SETTRKJ
D221 C3D5D3   	JP SETSECJ
D224 C3DBD3   	JP SETDMAJ
D227 C3E1D3   	JP READJ
D22A C34AD4   	JP WRITEJ
D22D C36AD4   	JP PRSTATJ
D230 C36BD4   	JP SECTRNJ
D233 C377D2   	JP SETENTRY
D236 C36ED4   	JP ZREENTJ
D239 C3DED2   	JP RTRAM
D23C C387D4   	JP LOADZ
D23F C3F2D2   	JP RAMWR
D242 C3FED2   	JP RAMRD
D245 C306D3   	JP RAMJP
              ;

ＲＴＲＡＭルーチンです。
Ｉ／Ｏアドレス９ＣＨにＦＦＨを出力してフルＲＡＭにします。
そのあとスタックポインタの値を元に戻して、ブレーク時に保存しておいたＰＣ（プログラムカウンタ）の値をスタックトップにＰＵＳＨしてリターンします。 

              ;
D2DE 3EFF     RTRAM:LD A,FF
D2E0 D39C     	OUT (9C),A
D2E2 F1       	POP AF
D2E3 ED7B99F0 	LD SP,(SPBF)
D2E7 228CF0   	LD (HLBF1),HL
D2EA 2A9BF0   	LD HL,(PCL)
D2ED E5       	PUSH HL
D2EE 2A8CF0   	LD HL,(HLBF1)
D2F1 C9       	RET
              ;

ワンボードマイコンでＣＰ／Ｍを！［第１８８回］
２０１２．８．３ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る