２０１８．１０．１９
前へ
次へ
ホームページトップへ戻る


１６ビットマイコンボードの製作
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
いつか使ってみるつもりで入手してそのまま置いてあった１６ビットＣＰＵのことを思い出しました。
ＡＭＤ社のＡＭ１８８です。
その名の通り、ＣＰＵコアは８０１８８互換の１６ビットＣＰＵです。
そのＡＭ１８８を使った１６ビットマイコンボードの製作記事です。
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜

［第１０１回］



●ストップウォッチプログラム（３）

ストップウォッチプログラムのアセンブルリストです。

2018/10/15  18:58  stwatch.LST
[00001]                     ;;;stop watch program for am188
[00002]                     ;18/10/15
[00003]                         ORG=8000
[00004]                         SEG8=FFF8
[00005]                         ADRSH=FFEF
[00006]                         ADRSL=FFEE
[00007]                         DARAH=FFED
[00008]                         DATAL=FFEC
[00009]                         ADDSP=01A1
[00010]                         LEDDP=01A4
[00011]                         KEY=0247
[00012]                     ;
[00013] 8000  BBF8FF            MOV BX,SEG8
[00014] 8003  B080              MOV AL,80
[00015] 8005  8807          TMR0:MOV [BX],AL
[00016] 8007  43                INC BX
[00017] 8008  75FB              JNZ TMR0 <8005>
[00018] 800A  E89781            CALL LEDDP <01A4>
[00019]                     ;tmr0 set
[00020] 800D  B850C3            MOV AX,C350;=50000
[00021] 8010  BA52FF            MOV DX,FF52;T0CMPA
[00022] 8013  EF                OUT DX,AX
[00023] 8014  E83082        STNBY:CALL KEY <0247>
[00024] 8017  FEC0              INC AL
[00025] 8019  74F9              JZ STNBY <8014>
[00026] 801B  FEC8              DEC AL
[00027] 801D  7407              JZ ZCLR <8026>
[00028] 801F  3C01              CMP AL,01
[00029] 8021  7415              JZ START <8038>
[00030] 8023  EBEF90            JMP STNBY <8014>
[00031]                     ;
[00032] 8026  33C0          ZCLR:XOR AX,AX
[00033] 8028  A3ECFF            MOV [*DATAL],AX
[00034] 802B  A3EEFF            MOV [*ADRSL],AX
[00035] 802E  BA50FF            MOV DX,FF50;T0CNT
[00036] 8031  EF                OUT DX,AX
[00037] 8032  E86C81        ZCLR2:CALL ADDSP <01A1>
[00038] 8035  EBDD90            JMP STNBY <8014>
[00039]                     ;
[00040] 8038  BA56FF        START:MOV DX,FF56;T0CON
[00041] 803B  B801C0            MOV AX,C001
[00042] 803E  EF                OUT DX,AX
[00043] 803F  E80582        START2:CALL KEY <0247>
[00044] 8042  FEC0              INC AL
[00045] 8044  7404              JZ START3;no key <804A>
[00046] 8046  3C03              CMP AL,03;[2] input?
[00047] 8048  7422              JZ STOP <806C>
[00048] 804A  ED            START3:IN AX,DX
[00049] 804B  A820              TEST AL,20;max count?
[00050] 804D  74F0              JZ START2;no <803F>
[00051] 804F  BEECFF            MOV SI,*DATAL
[00052] 8052  B104              MOV CL,04
[00053] 8054  8A04          START4:MOV AL,[SI]
[00054] 8056  0401              ADD AL,01
[00055] 8058  27                DAA
[00056] 8059  8804              MOV [SI],AL
[00057] 805B  7305              JNC START5 <8062>
[00058] 805D  46                INC SI
[00059] 805E  FEC9              DEC CL
[00060] 8060  75F2              JNZ START4 <8054>
[00061] 8062  B80100         START5:MOV AX,0001;clr MC
[00062] 8065  EF                OUT DX,AX
[00063] 8066  E83881            CALL ADDSP <01A1>
[00064] 8069  EBD490            JMP START2 <803F>
[00065]                     ;
[00066] 806C  B80140        STOP:MOV AX,4001
[00067] 806F  EF                OUT DX,AX
[00068] 8070  EBA290            JMP STNBY <8014>
[00069]                     ;
ADDSP        =01A1  ADRSH        =FFEF  ADRSL        =FFEE  DARAH        =FFED  
DATAL        =FFEC  KEY          =0247  LEDDP        =01A4  SEG8         =FFF8  
START        =8038  START2       =803F  START3       =804A  START4       =8054  
START5       =8062  STNBY        =8014  STOP         =806C  TMR0         =8005  
ZCLR         =8026  ZCLR2        =8032

プログラムを開始すると７セグメントＬＥＤに．．．．．．．．と表示してキー入力待ちになります。
このときキー入力は［０］と［１］以外は受け付けません。
［０］はタイマーをリセットします。
その結果７セグメントＬＥＤの表示は００００００００になります。
そのあとまたキー入力待ちになります。
［１］の入力でタイマーがスタートします。
Ｔｉｍｅｒ　０はシステムクロック（２０ＭＨｚ）の４クロックごとにカウントアップします。
２０／４＝５ＭＨｚですから０．２μｓｅｃごとにカウントアップすることになります。
Ｍａｘｃｏｕｎｔ　Ｃｏｍｐａｒｅ　ＡレジスタにはＣ３５０Ｈ（＝５００００）をセットします。
この結果Ｔｉｍｅｒ　０は０．２×５００００＝１００００μｓｅｃ＝１０ｍｓｅｃごとにＭａｘｃｏｕｎｔになりＭＣビットが１になります。
プログラムはＭＣビットを監視していてＭＣ＝１になったら７セグメントＬＥＤの最下位桁を＋１します。
７セグメントＬＥＤの表示は右２桁がＤＡＴＡＬ、その左２桁がＤＡＴＡＨ、その左２桁がＡＤＲＳＬ、一番左の２桁がＡＤＲＳＨの値をそれぞれ表示します。
ですからプログラムの動作は１０ｍｓｅｃごとにＤＡＴＡＬに＋１を加算し、繰り上がりがあればその上位桁（ＤＡＴＡＨ）に＋１を加算する、というように計算します。
時計の表示は十進ですから加算後に十進補正命令ＤＡＡを実行します。
７セグメントＬＥＤの右から３桁目が秒になります。
プログラムが複雑になるため分、時への換算は行ないません。
カウント中は［２］のみキー入力を受け付けます。
［２］をキー入力するとカウントストップします。
そのあとはカウント値の表示を保持したまま最初に戻って、［０］または［１］の入力を待ちます。
［１］を入力するとストップしたときの値からカウントアップを再開します。

Ｔｉｍｅｒ　０がＭａｘｃｏｕｎｔに達してＭＣビットが１になったあとの処理について。
Ｔｉｍｅｒ　０の設定は連続カウントになっていますから、ＭＣビットが１になったあとＴｉｍｅｒ　０は０からまたカウントを続けます。
このときＭＣビットは１のままですから、ＭＣビットだけ０にします。
それを行なっているのがＳＴＡＲＴ５：のところです。

こうやって実際にプログラムでＡＭ１８８の内蔵タイマーを使ってみた感想としては、割と扱い易いタイマーだと思います。

１６ビットマイコンボードの製作［第１０１回］
２０１８．１０．１９ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る